なんとかなるさね

マイコンをネタにブログを始めてみました


スポンサーサイト 

上記の広告は1ヶ月以上更新のないブログに表示されています。
新しい記事を書く事で広告が消せます。

--/--/--   blog-entry-   category: スポンサー広告

go page top

Arduino IDE|GadgetRenesas基板用IDE4GR 1.6.5(のようなもの)を作るには? (10) 

GadgetRenesas基板用IDE4GR 1.6.5/1.6.7(のようなもの)を作ってみることを考え始めたのですが、これまで
以下のファイルをどうやってその場所に配置するか先送りしてきたのですが、取り合えずイニシャライズ用の
バッチファイルを用意してファイルをコピーするようにしてみました。

ユーザプロファイルフォルダ\AppData\Roaming\Arduino15\package_GadgetRenesas_index.json (1.6.5)
ユーザプロファイルフォルダ\AppData\Local\Arduino15\package_GadgetRenesas_index.json (1.6.7)

なお、コピー元のファイルは以下に配置しておくものとしてあります。

arduino-1.6.5-r5\dist\package_GadgetRenesas_index.json
arduino-1.6.7\dist\package_GadgetRenesas_index.json

イニシャライズ用のバッチファイルは以下の通りです。また、この際ですので、1.6.7用のバッチファイルでは
シンボリックリンクも作成するようにしてみました。ですので、1.6.7用のバッチファイルは管理者として実行
する必要があります。

ファイル: arduino-1.6.5-r5\Arduino_with_GadgetRenesas_Boards_for_the_1st_time.bat
内容:

@echo off
rem This code is in the public domain. You may use, modify or distribute it freely.
title Arduino with GadgetRenesas Boards for the 1st time
if not exist "%USERPROFILE%\AppData\Roaming\Arduino15\" (
  echo MKDIR "%USERPROFILE%\AppData\Roaming\Arduino15\"
  MKDIR "%USERPROFILE%\AppData\Roaming\Arduino15\"
  echo\
)
if not exist "%USERPROFILE%\AppData\Roaming\Arduino15\" (
  pause
  goto exit
)
if not exist "%USERPROFILE%\AppData\Roaming\Arduino15\package_GadgetRenesas_index.json" (
  echo COPY "%~dp0dist\package_GadgetRenesas_index.json" "%USERPROFILE%\AppData\Roaming\Arduino15\package_GadgetRenesas_index.json"
  COPY "%~dp0dist\package_GadgetRenesas_index.json" "%USERPROFILE%\AppData\Roaming\Arduino15\package_GadgetRenesas_index.json"
  echo\
)
if not exist "%USERPROFILE%\AppData\Roaming\Arduino15\package_GadgetRenesas_index.json" (
  pause
  goto exit
)
start "" "%~dp0arduino.exe"
:exit

ファイル: arduino-1.6.7\Arduino_with_GadgetRenesas_Boards_for_the_1st_time.bat
内容:

@echo off
rem This code is in the public domain. You may use, modify or distribute it freely.
title Arduino with GadgetRenesas Boards for the 1st time
if not exist "%~dp0hardware\tools\avr\rl78-elf\" (
  echo MKLINK /D "%~dp0hardware\tools\avr\rl78-elf\" "..\gcc-rl78\rl78-elf\"
  MKLINK /D "%~dp0hardware\tools\avr\rl78-elf\" "..\gcc-rl78\rl78-elf\"
  echo\
)
if not exist "%~dp0hardware\tools\avr\rl78-elf\" (
  if exist "%~dp0hardware\tools\gcc-rl78\rl78-elf\" (
    echo Please Run this BAT file as Administrator.
    echo\
  )
  pause
  goto exit
)
if not exist "%USERPROFILE%\AppData\Local\Arduino15\" (
  echo MKDIR "%USERPROFILE%\AppData\Local\Arduino15\"
  MKDIR "%USERPROFILE%\AppData\Local\Arduino15\"
  echo\
)
if not exist "%USERPROFILE%\AppData\Local\Arduino15\" (
  pause
  goto exit
)
if not exist "%USERPROFILE%\AppData\Local\Arduino15\package_GadgetRenesas_index.json" (
  echo COPY "%~dp0dist\package_GadgetRenesas_index.json" "%USERPROFILE%\AppData\Local\Arduino15\package_GadgetRenesas_index.json"
  COPY "%~dp0dist\package_GadgetRenesas_index.json" "%USERPROFILE%\AppData\Local\Arduino15\package_GadgetRenesas_index.json"
  echo\
)
if not exist "%USERPROFILE%\AppData\Local\Arduino15\package_GadgetRenesas_index.json" (
  pause
  goto exit
)
start "" "%~dp0arduino.exe"
:exit

関連記事

2016/03/10   blog-entry-745   category: Arduino Lib & CrossGCC

go page top

上記広告は1ヶ月以上更新のないブログに表示されています。新しい記事を書くことで広告を消せます。